468a0e0d82
[QB] [GENERAL] /* Description: */ A few quests and one tooltip refer to Redstone Dust, but the normal dust-shaped version of the item is just called Redstone, unlike all the other dust-shaped resources that do have Dust in their name. This change would have saved me some time going from quest descriptions to actual recipes. (actually renaming Redstone to Redstone Dust would be more consistent in this modpack, but probably alienate a lot of people used to the normal MC naming of the item) Signed-off-by: Clarence "Sparr" Risher <sparr0@gmail.com>
52 lines
1.6 KiB
Plaintext
52 lines
1.6 KiB
Plaintext
#ignoreBracketErrors
|
|
|
|
import scripts.common.makeShaped as makeShaped;
|
|
|
|
/*
|
|
P2P Tunnel tooltips.
|
|
*/
|
|
<appliedenergistics2:part:469>.addTooltip(format.green(format.italic(
|
|
"Made by right-clicking ME P2P Tunnel with an energy conduit.")));
|
|
|
|
<appliedenergistics2:part:463>.addTooltip(format.green(format.italic(
|
|
"Made by right-clicking ME P2P Tunnel with a bucket.")));
|
|
|
|
<appliedenergistics2:part:462>.addTooltip(format.green(format.italic(
|
|
"Made by right-clicking ME P2P Tunnel with a chest.")));
|
|
|
|
<appliedenergistics2:part:467>.addTooltip(format.green(format.italic(
|
|
"Made by right-clicking ME P2P Tunnel with a torch.")));
|
|
|
|
<appliedenergistics2:part:461>.addTooltip(format.green(format.italic(
|
|
"Made by right-clicking ME P2P Tunnel with redstone.")));
|
|
|
|
/*
|
|
Channel-specific adjustments.
|
|
*/
|
|
if (<appliedenergistics2:controller> as bool) {
|
|
// ME Controller
|
|
recipes.removeByRecipeName("appliedenergistics2:network/blocks/controller");
|
|
makeShaped("me_controller", <appliedenergistics2:controller>,
|
|
["PFP",
|
|
"FAF",
|
|
"PFP"],
|
|
{ F : <ore:crystalPureFluix>,
|
|
P : <ore:plateDarkSteel>,
|
|
A : <appliedenergistics2:energy_acceptor>});
|
|
|
|
// Dense Conduit
|
|
assembler.recipeBuilder()
|
|
.inputs([<enderio:item_me_conduit> * 4, <ore:itemConduitBinder> * 5])
|
|
.outputs([<enderio:item_me_conduit:1> * 2])
|
|
.duration(80)
|
|
.EUt(16)
|
|
.buildAndRegister();
|
|
/*
|
|
Remove channel-specific items otherwise.
|
|
*/
|
|
} else {
|
|
mods.jei.JEI.removeAndHide(<enderio:item_me_conduit:1>);
|
|
recipes.removeByRecipeName("appliedenergistics2:network/cables/smart_fluix");
|
|
recipes.removeByRecipeName("appliedenergistics2:network/cables/dense_covered_fluix");
|
|
}
|